home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wonky Flux Batch 2019 02
/
Wonky_Flux_Batch_2019-02.zip
/
Wonky Flux Batch 2019-02
/
021 - HO Utilities - Clock Utility System.dsk
/
TIME.NO.ROM.bas
< prev
next >
Wrap
BASIC Source File
|
2019-02-16
|
1KB
|
31 lines
10 DIM CL(30),FMT(30)
20 HOME : INPUT "SLOT:";SLOT: IF SLOT <1 OR SLOT >7 THEN PRINT CHR$(7);: GOTO 20
40 GOSUB 2300: REM READ FORMAT DATA
50 GOSUB 2000: REM INITIALIZE PIA
60 GOSUB 2100: REM READ CLOCK
70 VTAB 10: HTAB 10: PRINT T$
80 IF PEEK( -16384) <128 THEN 60
90 POKE -16368,0: END
2000 REM SETUP PIA
2010 PA = 49280 +SLOT *16: REM $C080 + $N0
2020 CA = PA +1:PB = PA +2:CB = PA +3
2030 IF PEEK(CB) < >0 THEN 2060: REM PIA ALREADY SET UP
2040 POKE CA,0: POKE CB,0: POKE PA,0: POKE PB,255: REM SET DIRECTION REGISTERS
2050 POKE CA,4: POKE CB,4: REM POINT AT DATA REGISTERS
2060 RETURN
2100 REM READ CLOCK USING FORMAT
2110 T$ = "": FOR I = 1 TO NC
2120 POKE PB,16: REM HOLD CLOCK
2130 D = FMT(I): IF D >127 THEN 2170
2140 M = 16: IF D = 56 OR D = 53 THEN M = 4
2150 POKE PB,D:T = PEEK(PA): REM READ THE DIGIT
2160 D = T - INT(T/M) *M +176
2170 T$ = T$ + CHR$(D)
2180 NEXT
2190 POKE PB,47: RETURN
2299 REM -------------------
2300 REM "W MM/DD/YY HH:MM:SS" FORMAT
2310 DATA 54,160,58,57,175,56,55,175,60,59,160,53,52,186,51,50,186,49,48,0
2320 NC = 0
2330 READ D: IF D = 0 THEN RETURN
2340 NC = NC +1:FMT(NC) = D: GOTO 2330